Sub laMacro()
    'Placé en début de macro:
    'Si une erreur survient, on va à la ligne "errorHandler"
    On Error GoTo errorHandler
    
    '
    'La procédure
    '
    
    'Permet de sortir de la procédure et évite la gestion d'erreur (errorHandler), si la macro
    's'est déroulée sans encombre.
    Exit Sub
    
errorHandler:
    'indique le numéro et la description de l'erreur survenue
    MsgBox Err.Number & vbLf & Err.Description
End Sub

Sub UtilisationInstructionResume()
    Dim i As Integer, j As Integer
    
    On Error GoTo ErrorHandler
    
    'Par défaut i=0 (et va provoquer une erreur)
    j = 5 / i
    MsgBox j
    
    
    Exit Sub

ErrorHandler:
    MsgBox "Erreur: " & Err.Number & vbCrLf & Err.Description
    If i = 0 Then i = 1
    'Reprend l'exécution au niveau de la ligne à l'origine de l'erreur.
    Resume
    
End Sub

Sub laMacro()
    Dim x As Double
    
    'Permet d'atteindre la ligne "errorHandler" si une erreur survient.
    On Error GoTo errorHandler
    
    MsgBox 5 / 2 'Pas de problème
    x = 5 / 0 'Division par zero = erreur
    MsgBox x
    
errorHandler:

    'Invalide le gestionnaire d'erreur.
    On Error GoTo 0
    
    'Provoque une erreur d'exécution car il n'y a plus de gestion.
    MsgBox 5 / 0
    
End Sub

Sub laMacro()
    Dim Ws As Worksheet
    
    'Evite le message d'erreur si la feuille n'existe pas.
    On Error Resume Next
    Set Ws = ThisWorkbook.Worksheets("NomFeuille")
    On Error GoTo 0
	    
    '(Ws = Nothing quand l'objet attribué à la variable n'existe pas)
    If Not Ws Is Nothing Then
        MsgBox "La feuille existe dans le classeur."
        Else
        MsgBox "La feuille n'existe pas dans le classeur."
    End If
End Sub	

							
Sub laMacro()
    Dim i As Integer
    Dim Cible As Byte
    
    On Error Resume Next
    
    For i = 1 To 5
        'Renvoie une valeur aléatoire entre 1 et 400
        Randomize
        Cible = Int((400 * Rnd) + 1)
        'Une erreur survient si le résultat est supérieur à 255
        '(Les variables Byte acceptent uniquement des valeurs entre 0 et 255)
        
        If Err.Number <> 0 Then
            MsgBox "Erreur"
            'Réinitialise les propriétés de l'objet Err.
            Err.Clear
        End If
        
    Next i
End Sub

Sub DescriptionErreur()
    Dim Obj As OLEObject
    
    On Error Resume Next
    
    'Déclenchement erreur:
    'Spécifie un objet qui n'existe pas dans la feuille
    Set Obj = Worksheets("Feuil1").Textbox1
    
    MsgBox Err.Description
End Sub

Sub FichierAideErreurs()
    Dim x As Double
    
    On Error Resume Next
    'La division par zéro va provoquer une erreur.
    x = 5 / 0
    
    MsgBox Err.HelpFile
End Sub

Dim Msg As String
Dim Cellule As Range

On Error Resume Next
'Va provoquer une erreur: Cells(0, 1) ne peut pas exister
Set Cellule = Cells(0, 1)

MsgBox Err.HelpContext

Msg = "Cliquez sur le bouton AIDE pour consulter la rubrique relative à cette erreur."
MsgBox Msg, vbMsgBoxHelpButton, "Erreur", Err.HelpFile, Err.HelpContext

Option Explicit

Private Const FORMAT_MESSAGE_FROM_SYSTEM = &H1000
Private Const FORMAT_MESSAGE_IGNORE_INSERTS = &H200

Private Declare Function FormatMessage Lib "kernel32" Alias "FormatMessageA" _
    (ByVal dwFlags As Long, lpSource As Any, ByVal dwMessageId As Long, ByVal dwLanguageId As Long, _
    ByVal lpBuffer As String, ByVal nSize As Long, Arguments As Long) As Long


'--- Permet de retrouver les coordonnées d'une fenêtre à partir de son Handle
Declare Function GetWindowRect Lib "user32" _
  (ByVal Hwnd As Integer, ByRef lpRect As RECT) As Integer

Public Type RECT
    Left As Long
    Top As Long
    Right As Long
    Bottom As Long
End Type
  

Private Sub PrintWindowCoordinates(ByVal Hwnd As Integer)
    Dim rectWindow As RECT

  'Une erreur survient si la fonction renvoie 0
  If GetWindowRect(Hwnd, rectWindow) = 0 Then
      
      'Affiche la valeur d'erreur et la description.
      MsgBox "Valeur d'erreur: " & Err.LastDLLError & vbCrLf & _
        LastDLLErrorDescription(Err.LastDLLError)
  
  Else
      Debug.Print (rectWindow.Bottom)
      Debug.Print (rectWindow.Left)
      Debug.Print (rectWindow.Right)
      Debug.Print (rectWindow.Top)
  End If
  
End Sub
'---


'Cette fonction permet de retrouver la description associée à la valeur d'erreur
'de la DLL.
'Source:
'http://undim.blogspot.com/2006/12/function-that-microsoft-forgot-to.html
Public Function LastDLLErrorDescription(LastDLLError As Long) As String
    Dim strBuffer As String
    Dim LenBuff As Long
    Dim cRes As Long
    
    LenBuff = 256
    strBuffer = Space$(LenBuff)
    
    cRes = FormatMessage(FORMAT_MESSAGE_FROM_SYSTEM Or FORMAT_MESSAGE_IGNORE_INSERTS, _
        0&, LastDLLError, 0&, strBuffer, LenBuff, 0&)
    
    If cRes = 0 Then
    strBuffer = "FormatMessage API execution Error. Couldn't fetch error description."
    Else
    strBuffer = Left$(strBuffer, cRes - 2)
    End If
    
    LastDLLErrorDescription = strBuffer
End Function



Sub Test()
    PrintWindowCoordinates 1
End Sub

Sub lireCommentaire()
    Dim Cm As Comment
    
    On Error GoTo Fin
    
    Set Cm = Range("A1").Comment
    MsgBox Cm.Text
    
    
    Exit Sub
Fin:
    If Err.Number = 91 Then MsgBox "Il n'y a pas de commentaire dans la cellule."
End Sub

Sub Macro_TestRaise()
    Dim Resultat As Variant
    
    On Error GoTo Fin

    ' Affiche la boîte de dialogue sur la position 100, 100.
    Resultat = InputBox("Saisissez une valeur entre 0 et 9:", "Le titre", 0)
    If Resultat = "" Then Exit Sub
     
    'Vérifie si la saisie est numérique
    If Not IsNumeric(Resultat) Then _
        Err.Raise 5010, , "Type de donnée non compatible."
    
    'Vérifie si la saisie est un chiffre en 0 et 9
    If Len(Resultat) > 1 Then _
        Err.Raise 5020, , "La valeur doit être comprise entre 0 et 9", _
        "C:\MonFichierAide.chm", 1000028
    
    
    '
    'La procédure
    '
    '
    
    
Exit Sub
Fin:

MsgBox "Erreur: " & Err.Number & vbCrLf & _
    Err.Description, vbMsgBoxHelpButton, , Err.HelpFile, Err.HelpContext
End Sub

Sub laProcedure()
4     Dim x As Integer

5     x = 0    
6     On Error GoTo errHandler
    
8     x = 5 / 0 'Création erreur (division par zero)
    
    
10     Exit Sub
11 errHandler:
12     MsgBox "Une erreur est survenue, Ligne: " & Erl() & _
        vbCrLf & "Numéro d'erreur: " & Err.Number & vbCrLf & Err.Description
14 End Sub

Sub ListeErreur()
    Dim Cible As Integer
    Dim I As Integer, j As Integer
    
    j = 1
    On Error Resume Next
    
    For I = 1 To 800 'Adaptez le nb de codes erreurs
        Cible = I
        Err.Clear
        Err.Raise Cible
        
        j = j + 1
        Cells(j, 1) = Err.Number
        Cells(j, 2) = Err.Description
        Cells(j, 3) = Err.HelpFile
        Cells(j, 4) = Err.HelpContext
    Next I

End Sub

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Excel.Range, Cancel As Boolean)
    Dim Fso As Object, oFichier As Object
    Dim Ligne As Integer
    Dim Fichier As String
    
    Ligne = ActiveCell.Row

    Set Fso = CreateObject("Scripting.FileSystemObject")
    Set oFichier = Fso.GetFile(Cells(Ligne, 3))
    Fichier = Fso.GetFileName(oFichier)

    'Affiche l'aide
    Application.Help Fichier, Cells(Ligne, 4)

End Sub

Option Explicit

Private Sub Worksheet_Calculate()
'Testé sous XP
Dim Valeur As Range
Dim Resultat As String, Message As String

For Each Valeur In Worksheets("Feuil1").UsedRange
    If WorksheetFunction.IsError(Valeur) = True Then
        
        'Affiche les flèches d'audit qui passent par les antécédents
        Valeur.ShowErrors
        
        Select Case Valeur
        Case CVErr(xlErrDiv0)
        Resultat = "#DIV/0!"
        Case CVErr(xlErrNA)
        Resultat = "#N/A"
        Case CVErr(xlErrName)
        Resultat = "#NOM?"
        Case CVErr(xlErrNull)
        Resultat = "#NULL!"
        Case CVErr(xlErrNum)
        Resultat = "#NOMBRE!"
        Case CVErr(xlErrRef)
        Resultat = "#REF!"
        Case CVErr(xlErrValue)
        Resultat = "#VALEUR!"
        End Select
        
        MsgBox "Il y a une erreur de type " & Resultat _
            & " dans la formule de la cellule " & Valeur.Address
    End If
Next

Message = MsgBox("Voulez vous ouvir l'aide en ligne Excel?", _
    vbYesNo, "Informations complementaires sur les types d'erreur")

'Adaptez le nom du fichier et l' HelpContextId en fonction de la version d'excel
If Message = vbYes Then Application.Help "XLMAIN10.chm", 60309 'Excel2002
'If Message = vbYes Then Application.Help "XLMAIN09.chm", 60309'pour Excel2000
End Sub

Sub effacerFlechesAudit()
Worksheets("Feuil1").ClearArrows
End Sub

				
Sub identifierCellulesContenantErreurs()
    Dim Plage As Range, Cible As Range
    
    'Recherche dans la plage A1:A20
    Set Plage = Range("A1:A20")
    
    On Error Resume Next
    Set Cible = Plage.SpecialCells(xlCellTypeFormulas, xlErrors)
    If Not Cible Is Nothing Then MsgBox Cible.Address(0, 0)
End Sub

MsgBox Error(9)

Sub MessageSiErreurFormuleDansCellule()
    If IsError(Range("A1")) = True Then _
        MsgBox "Il y a une erreur dans la cellule."
End Sub

Sub suppressionLigne_SiErreur_Div0()
    Dim x As Integer
    
    For x = 20 To 1 Step -1
        'Vérifie si les cellules de la colonne A contiennent une erreur
        If WorksheetFunction.IsError(Range("A" & x)) = True Then
            'Supprime la ligne s'il s'agit d'une erreur #DIV/0!
            If CVErr(xlErrDiv0) = Range("A" & x) Then _
                Rows(x).EntireRow.Delete
        End If
    Next x
End Sub