'Déclare la variable objet Worksheet 
Dim Ws As Worksheet 

'Attribue la référence objet à la variable 
'La feuille est un Objet: la variable doit donc être précédée de l'instruction Set lors de l'attibution. 
Set Ws = Worksheets("Feuil2") 
'Manipulation de l'objet: 
'Exemple pour renvoyer l'index (position) de la feuille dans le classeur 
MsgBox "Index de la feuille nommée '" & Ws.Name & "': " & Ws.Index

'Déclare la variable objet Worksheet 
Dim Ws As Worksheet 

'Boucle sur toutes les feuille de calcul du classeur. Les onglets graphiques ne sont pas pris 
'en compte. 
'ThisWorkbook correspond à l'objet classeur contenant la macro 
For Each Ws In ThisWorkbook.Worksheets 
    'Renvoie le nom de chaque feuille 
    MsgBox Ws.Name 
Next Ws 

'Déclare la variable objet 
Dim Ws As Object 

'Boucle sur tous les onglets du classeur 
'ThisWorkbook correspond à l'objet classeur contenant la macro 
For Each Ws In ThisWorkbook.Sheets 
    'Renvoie le nom de chaque onglet 
    MsgBox Ws.Name 
Next Ws


'Nota:
'La clause TypeOf permet de contrôler vers quel objet de l'application pointe la variable. 
'Pour retrouver le nom de toutes les feuilles graphiques dans le classeur actif, vous pouvez utiliser:
  	'Dim Sh As Object
  	'For Each Sh In ActiveWorkbook.Sheets
  	'If TypeOf Sh Is Chart Then MsgBox Sh.Name
  	'Next

Worksheets("Feuil1").Activate

'Ajoute une feuille et la positionne à la fin du classeur.
ThisWorkbook.Sheets.Add After:=Sheets(ThisWorkbook.Sheets.Count)

'Exemple pour ajouter 3 feuilles:
ThisWorkbook.Sheets.Add After:=Sheets(ThisWorkbook.Sheets.Count), Count:=3

'Lance le calcul dans la 1ere feuille du classeur
Worksheets(1).Calculate 

Dim Ch As ChartObject

Application.ScreenUpdating = False

'Boucle sur les graphiques de la feuille active
For Each Ch In ActiveSheet.ChartObjects
    'Récupère le nom de chaque graphique
    'MsgBox Ch.Name

    With Ch
        .Left = 50 'position horizontale
        .Top = 20 + (230 * (Ch.Index - 1)) 'position verticale
        .Height = 200 'hauteur graphique
        .Width = 350 'largeur graphique
    End With
Next Ch

Application.ScreenUpdating = True

'Permet de renommer le 1er graphique de la feuille active
ActiveSheet.ChartObjects(1).Name = "Le Graphique"

'Vérifie le nom attribué
MsgBox ActiveSheet.ChartObjects(1).Name

'Permet de renommer un graphique nommé "Le Graphique"
ActiveSheet.ChartObjects("Le Graphique").Name = "Nouveau Nom"

'Vérifie le nom attribué
MsgBox ActiveSheet.ChartObjects(1).Name

Dim IgnoreMajuscule As Boolean
Dim Suggestion As Boolean
Dim MonDico As String

'indique le nom de fichier du dictionnaire personnalisé à examiner si le mot
'n'est pas trouvé dans le dictionnaire principal.(Facultatif)
MonDico = ""

'Affiche une liste de suggestions lorsqu'un mot est mal orthographié.(Facultatif)
Suggestion = True
'Permet d'ignorer les mots en majuscules.(Facultatif)
IgnoreMajuscule = True

Worksheets("Feuil1").CheckSpelling MonDico, IgnoreMajuscule, Suggestion

Worksheets("Feuil1").ClearArrows

'Crée une copie de la Feuil1 et la positionne à la fin du classeur.
Worksheets("Feuil1").Copy After:=Sheets(Sheets.Count)

'Crée une copie de la Feuil1 dans un nouveau classeur
Worksheets("Feuil1").Copy
'Sauvegarde la copie
ActiveWorkbook.SaveAs "C:\LaFeuilleDupliquee.xls"
'Ferme le classeur sauvegardé
ActiveWorkbook.Close True

Worksheets("Feuil2").CircleInvalid

Worksheets("Feuil2").ClearCircles

'DisplayAlerts = False permet de ne pas afficher le message d'alerte qui survient
'lorsque l'on supprime un onglet.
Application.DisplayAlerts = False
'Suppression de la feuille nommée "Feuil2"
Worksheets("Feuil2").Delete
'Ne pas oublier de réinitialiser DisplayAlerts à True
Application.DisplayAlerts = True

Dim Cellule As Range

'--- Utilise Evaluate pour récupérer le contenu de la cellule A1
MsgBox Worksheets("Feuil1").Evaluate("A1")
'Equivalent:
MsgBox Worksheets("Feuil1").[A1]


'--- Utilise Evaluate pour définir un objet Range
Set Cellule = Worksheets("Feuil1").[A1]
'Applique la couleur verte dans la cellule
Cellule.Interior.ColorIndex = 4

Dim Tableau As Variant
Dim ArgType As Long

'--- Précise comment doit être copiée la plage de cellules
'xlFillWithAll est la valeur par défaut si l'agument n'est pas spécifié
ArgType = xlFillWithAll 'copie tout
'ArgType = xlFillWithContents 'contenu des cellules
'ArgType = xlFillWithFormats 'Le format des cellules
'---

Tableau = Array("Base", "Feuil1", "Feuil3", "Feuil6")
'Copie la plage A1:A10 de la feuille "Base" vers les feuilles spécifiées 
'dans le tableau Array("Feuil1", "Feuil3", "Feuil6"):
    'Nota:
    'La feuille source doit être aussi indiquée dans le tableau
Sheets(Tableau).FillAcrossSheets Worksheets("Base").Range("A1:A10"), ArgType

Worksheets.FillAcrossSheets Worksheets("Feuil1").Range("A1:E5"), xlFillWithAll

Sub TrierFeuilles()
    Dim WS As Object
    Dim I As Byte
    
    Application.ScreenUpdating = False
        For Each WS In ActiveWorkbook.Sheets
            For I = 2 To ActiveWorkbook.Sheets.Count
                If Sheets(I - 1).Name > Sheets(I).Name Then _
                    Sheets(I - 1).Move After:=Sheets(I)
            
            Next I
        Next WS
    Application.ScreenUpdating = True
End Sub

Dim Ws As Worksheet
Dim Obj As OLEObject
Dim laMacro As String
Dim x As Integer

Set Ws = Sheets.Add 'Ajoute une nouvelle feuille
    
'ajoute un CommandButton dans la nouvelle feuille
Set Obj = Ws.OLEObjects.Add("Forms.CommandButton.1")
With Obj
    .Name = "monBouton" 'renomme le bouton
    .Left = 50 'position horizontale par rapport au bord gauche de la feuille
    .Top = 50 'position verticale par rapport au bord haut de la feuille
    .Width = 150 'largeur
    .Height = 30 'hauteur
    .Object.Caption = "Supprimer données feuille"
End With

'Ajoute la procédure dans la feuille
With ThisWorkbook.VBProject.VBComponents(ActiveSheet.Name).CodeModule
    .CreateEventProc "Click", "monBouton"
    x = .ProcStartLine("monBouton_Click", vbext_pk_Proc)
    .InsertLines x + 2, "Cells.Clear"
End With

Dim Obj As OLEObject
    
For Each Obj In Feuil1.OLEObjects
    'Nom de l'objet.
    Debug.Print Obj.Name
    
    'Type de contrôle.
    '(Renvoie une erreur si la feuille contient des objets type fichiers insérés)
    Debug.Print TypeName(Obj.Object)
Next Obj

Dim Obj As OLEObject
    
'Boucle sur les objets contenus dans la feuille.
For Each Obj In Feuil1.OLEObjects
    'Vérifie s'il s'agit d'un contrôle ActiveX
    If Obj.ShapeRange.Type = msoOLEControlObject Then
        'Vérifie s'il s'agit d'un TextBox et en récupère le contenu si c'est le cas.
        If TypeName(Obj.Object) = "TextBox" Then MsgBox Obj.Object.Value
    End If
Next Obj

Dim Obj As OLEObject
    
'Boucle sur les objets contenus dans la feuille.
For Each Obj In Feuil1.OLEObjects
    'Vérifie s'il s'agit d'un contrôle ActiveX
    If Obj.ShapeRange.Type = msoOLEControlObject Then
        'Vérifie s'il s'agit d'un TextBox et en récupère le contenu si c'est le cas.
        If TypeOf Obj.Object Is MSForms.TextBox Then MsgBox Obj.Object.Value
    End If
Next Obj

Dim i As Byte
For i = 1 To 4
    'Boucle sur 4 Textbox nommés "Textbox1" à "Textbox4" pour y afficher
    'les données contenues dans les cellules A1 à A4, dans la Feuil2.
    Feuil1.OLEObjects("TextBox" & i).Object.Text = Feuil2.Cells(i, 1)
Next

Dim Ws As Worksheet
Dim Fichier As String

'Indique la feuille qui va recevoir l'objet
Set Ws = ThisWorkbook.Worksheets("Feuil1")

'Définit le fichier à insérer
Fichier = "C:\Documents and Settings\michel\le document.doc"

'Insère le document Word, sous forme d'icone, dans la feuille
Ws.OLEObjects.Add Filename:=Fichier, _
    Link:=False, DisplayAsIcon:=True, IconIndex:=0, _
    IconLabel:=Fichier

'Copie la plage de cellules A1:A10 dans la Feuil1
Worksheets("Feuil1").Range("A1:A10").Copy

'Effectue le collage dans la plage B1:B10 de la Feuil2
Worksheets("Feuil2").Paste Destination:=Worksheets("Feuil2").Range("B1:B10")
'ou
'Worksheets("Feuil2").Paste Destination:=Worksheets("Feuil2").Range("B1")

'Permet de désactiver le presse papier
Application.CutCopyMode = False

'
'Nécéssite d'activer la référence "Microsoft Forms 2.0 Object Library"
'
Dim Cible As dataObject

'-- Copie la plage de cellules A1:A10 dans la Feuil1 ---
Worksheets("Feuil1").Range("A1:A10").Copy

'Effectue un collage avec liaison dans la Feuil3
With Worksheets("Feuil3")
    .Activate
    .Range("E5").Select
    .Paste link:=True
End With
'-------------------------------------------------------

'--- permet de vider le presse papier ---
Set Cible = New dataObject
Cible.setText ""
Cible.putInClipboard
Set Cible = Nothing
'----------------------------------------

'Effectue une copie du 1er graphique contenu dans la feuille nommée "Feuil1"
Worksheets("Feuil1").ChartObjects(1).Copy
'Active la Feuil2
Worksheets("Feuil2").Activate
'Colle le graphique au format Image MetaFichier dans la Feuil2
Worksheets("Feuil2").PasteSpecial Format:="Picture (Enhanced Metafile)", _
    Link:=False, DisplayAsIcon:=False

Dim Pvt As PivotTable
    
'Définit le TCD contenu dans la feuille
Set Pvt = Worksheets("Feuil4").PivotTables("Tableau croisé dynamique1")
'Met à jour le TCD
Pvt.RefreshTable

Worksheets("Feuil4").PivotTableWizard _
    SourceType:=xlDatabase, _
    SourceData:=Worksheets("Feuil1").Range("A1:E100").Address(, , xlR1C1, True), _
    TableDestination:=Worksheets("Feuil4").Range("B10"), _
    TableName:="TCD_1"

With Worksheets("Feuil4").PivotTables("TCD_1")
    .AddFields RowFields:="Ville"
    .PivotFields("ChiffreAffaire").Orientation = xlDataField
End With

'Imprime la totalité de la feuille
Worksheets("Feuil1").PrintOut

'Imprime les pages 2 à 3
Worksheets("Feuil1").PrintOut From:=2, To:=3

'Imprime la 1ere page en 2 exemplaires
Worksheets("Feuil1").PrintOut From:=1, To:=1, Copies:=2

Worksheets("Feuil1").PrintPreview

'Protège la feuille.
Worksheets("Feuil1").Protect

'Protège la feuille et autorise l'utilisation des tableaux croisés dynamiques.
Worksheets("Feuil1").Protect AllowUsingPivotTables:=True

'Protège la feuille en spécifiant un mot de passe
Worksheets("Feuil1").Protect Password:="MotDePasse"

'Protège la feuille et autorise toutes les modifications effectuées par macro.
'/!\ L'option UserInterfaceOnly doit être réinitialisée à chaque ouverture du classeur.
Worksheets("Feuil1").Protect UserInterfaceOnly:=True

Worksheets("Feuil1").ResetAllPageBreaks

Dim Scn As Scenario

'Définit le scénario à utiliser (nommé "TestScenario" dans l'exemple)
Set Scn = Worksheets("Feuil1").Scenarios("TestScenario")
'Le scénario peut aussi être spécifié par son index dans la feuille
'Set Scn = Worksheets("Feuil1").Scenarios(1)

'Lance le scénario
Scn.Show

'Sélectionne le dernièr onglet du classeur.
Sheets(Sheets.Count).Select

Worksheets("Feuil1").SetBackgroundPicture _
    "C:\Documents and Settings\mimi\dossier Images\fourmiz.JPG"

'Pour enlever l'image de fond:
'Worksheets("Feuil1").SetBackgroundPicture ""

Worksheets("Feuil1").ShowAllData

Worksheets("Feuil1").ShowDataForm
'La suite de la procédure s'execute lorsque la boite de dialogue est refermée.
MsgBox "Fermeture du formulaire"

Worksheets("Feuil3").Unprotect
'Si la feuille est protégée par mot de passe:
'Worksheets("Feuil3").Unprotect "MotDePasse"

Dim appExcel As Excel.application
Dim wbExcel As Excel.Workbook
Dim wsExcel As Excel.Worksheet

'Ouverture de l'application
Set appExcel = CreateObject("Excel.Application")
appExcel.Visible = True

'Ajout d'un classeur
Set wbExcel = appExcel.Workbooks.Add

'Définit la feuille par défaut
Set wsExcel = wbExcel.ActiveSheet

Debug.Print wsExcel.application

Dim Fltr As Filter
Dim Resultat As String

If Worksheets("Feuil1").AutoFilterMode Then
    For Each Fltr In Worksheets("Feuil1").AutoFilter.Filters
        If Fltr.On Then
            
            Resultat = "1er critère:" & Fltr.Criteria1 & vbCrLf
            
            If Fltr.Operator Then
                Resultat = Resultat & "Opérateur:" & Fltr.Operator & vbCrLf
                Resultat = Resultat & "2eme critère:" & Fltr.Criteria2
            End If
            
            MsgBox Resultat
        End If
    Next Fltr
End If

ActiveWorkbook.Names.Add Name:="Zone1", _
    RefersTo:="=Feuil1!" & Feuil1.AutoFilter.Range.SpecialCells(xlCellTypeVisible).Address

'Indique s'il y a un filtre automatique placé dans la feuille
MsgBox Worksheets("Feuil1").AutoFilterMode


'Enlève le filtre automatique de la Feuil1
Worksheets("Feuil1").AutoFilterMode = False

Dim NumLigne As Integer, NumColonne As Integer

NumLigne = 10
NumColonne = 1

'Ecrit dans la cellule A10 de la Feuil1
Worksheets("Feuil1").Cells(NumLigne, NumColonne).Value = "essai"


'Affecte la taille de police 12 à toute les cellules de la feuille
Worksheets("Feuil1").Cells.Font.Size = 12

Dim oCirc As Range

On Error Resume Next
Set oCirc = Worksheets("Feuil1").CircularReference
On Error GoTo 0

If oCirc Is Nothing Then
    MsgBox "Il n'y a pas de référence circulaire dans la feuille."
    Else
    MsgBox "Il y a une référence circulaire dans cellule: " & oCirc.Address & _
      vbCrLf & oCirc.Formula
End If

Dim Ws As Worksheet

For Each Ws In ThisWorkbook.Worksheets
    MsgBox Ws.Name & " ---> " & Ws.CodeName
Next Ws

'---
'Nécessite dd'activer la référence "Microsoft Visual Basic For Application Extensibility 5.3"
'---
'
'Attention: Le CodeName n'accepte pas les espaces dans le nom
'
With ThisWorkbook
    .VBProject.VBComponents(.Worksheets("historique2006").CodeName).Name = "NouveauNom"
End With

'Applique la couleur jaune dans la 2eme colonne
Worksheets("Feuil1").Columns(2).Interior.ColorIndex = 6

'Applique la couleur jaune dans les colonnes E à G
Worksheets("Feuil1").Columns("E:G").Interior.ColorIndex = 6

Dim Cmt As Comment

For Each Cmt In Feuil1.Comments
    'Affiche le contenu des commentaires
    MsgBox Cmt.Text & vbCrLf & vbCrLf & "Dans la cellule " & Cmt.Parent.Address
Next Cmt

If Not IsEmpty(Worksheets("Feuil1").ConsolidationSources) Then
    Select Case Worksheets("Feuil1").ConsolidationFunction
        Case xlAverage: MsgBox "Moyenne"
        Case xlCount: MsgBox "Nombre"
        Case xlCountNums: MsgBox "Nb"
        Case xlMax: MsgBox "Max"
        Case xlMin: MsgBox "Min"
        Case xlProduct: MsgBox "Produit"
        Case xlStDev: MsgBox "EcartType"
        Case xlStDevP: MsgBox "EcartTypeP"
        Case xlSum: MsgBox "Somme"
        Case xlUnknown: MsgBox "Inconnu"
        Case xlVar: MsgBox "Var"
        Case xlVarP: MsgBox "VarP"
    End Select
End If

Dim Tableau() As Variant

Tableau = Worksheets("Feuil1").ConsolidationOptions

MsgBox "Etiquettes dans la ligne du haut: " & Tableau(1) & vbCrLf & _
    "Etiquettes dans la colonne de gauche: " & Tableau(2) & vbCrLf & _
    "Liaisons vers les données sources: " & Tableau(3)

Dim Tableau2() As Variant
Dim x As Byte

If Not IsEmpty(Worksheets("Feuil1").ConsolidationSources) Then
    
    Tableau2 = Worksheets("Feuil1").ConsolidationSources
    
    For x = 1 To UBound(Tableau2)
        MsgBox Tableau2(x)
    Next x
    
End If

'Compte le nombre de feuilles de calcul
'(les onglets graphiques ne sont pas pris en compte)
MsgBox ThisWorkbook.Worksheets.Count

'Compte le nombre d'onglets
MsgBox ThisWorkbook.Sheets.Count

'Ajoute une propriété personnelle dans la feuille
Worksheets("Feuil1").CustomProperties.Add Name:="NomMetaData", Value:="Donnée MetaData"	

'Lit la 1ere propriété personnelle de la feuille
With Worksheets("Feuil1").CustomProperties.Item(1)
    MsgBox .Name & ": " & .Value
End With

Worksheets("Feuil1").DisplayPageBreaks = True
MsgBox "Affichage des sauts de page: " & Worksheets("Feuil1").DisplayPageBreaks

'Vérifie le statut du filtre automatique (valeur Faux par défaut)
MsgBox Worksheets("Feuil1").EnableAutoFilter
'Active l'autorisation de filtre automatique					
Worksheets("Feuil1").EnableAutoFilter = True
'Vérifie le statut du filtre automatique après la modification de la propriété
MsgBox Worksheets("Feuil1").EnableAutoFilter
'Protège la feuille
Worksheets("Feuil1").Protect

'Protège la feuille
Worksheets("Feuil1").Protect userInterfaceOnly:=True
'Autorise l'utilisation du filtre
Worksheets("Feuil1").EnableAutoFilter = True

'Vérifie le statut du recalcul automatique
MsgBox Worksheets("Feuil1").EnableCalculation
'Empèche le recalcul automatique dans la Feuil1
Worksheets("Feuil1").EnableCalculation = False
'Vérifie le statut du recalcul automatique après la modification de la propriété
MsgBox Worksheets("Feuil1").EnableCalculation

'Tous les calculs sont immédiatement effectuées lorsque la propriété prend la valeur True
Worksheets("Feuil1").EnableCalculation = True

'Autorise l'accès aux symboles du plan
Worksheets("Feuil1").EnableOutlining = True
'Protège la feuille
Worksheets("Feuil1").Protect userInterfaceOnly:=True
  'Nota:
  'La valeur de la propriété peut être modifiée après la mise en place 
  'de la protection.

'Autorise la manipulation des TCD dans la feuille protégée
Worksheets("Feuil1").EnablePivotTable = True
'Protège la feuille
Worksheets("Feuil1").Protect contents:=True, userInterfaceOnly:=True
  'Nota:
  'La valeur de la propriété peut être modifiée après la mise en place 
  'de la protection.

'Définit le type de sélection autorisé avant de protéger la feuille:
'Permet de sélectionner uniquement les cellules déverrouillées.
Worksheets("Feuil1").EnableSelection = xlUnlockedCells
'Protège la feuille
Worksheets("Feuil1").Protect UserInterfaceOnly:=True
  'Nota:
  'La valeur de la propriété peut être modifiée après la mise en place
  'de la protection.

With Worksheets("Feuil1")
    If .FilterMode = True Then .ShowAllData
End With

Dim Hpb As HPageBreak

'Compte le nombre de pages dans la feuille
MsgBox "Cette feuille contient " & Worksheets("Feuil1").VPageBreaks.Count + _
    Worksheets("Feuil1").HPageBreaks.Count + 1 & " pages"

'Boucle sur les sauts de pages horizontaux
For Each Hpb In Worksheets("Feuil1").HPageBreaks
    'Renvoie l'adresse de chaque cellule suivant le saut de page
    MsgBox Hpb.Location.Address
Next Hpb

Dim Hpk As Hyperlink

'Boucle sur les liens hypertextes de la feuille
For Each Hpk In Worksheets("Feuil1").Hyperlinks
    MsgBox Hpk.Address & vbCrLf & Hpk.Range.Address
Next Hpk

'Ajoute un lien hypertexte dans la cellule B5
Worksheets("Feuil1").Hyperlinks.Add Anchor:=Range("B5"), _
    Address:="http://www.developpez.com", TextToDisplay:="Mon lien hypertexte"

Sub Test()
    CreeSommaire ThisWorkbook
End Sub


Sub CreeSommaire(Wb As Workbook)
    Dim Ws As Worksheet
    Dim I As Byte
    Dim Cible As String
    
    'Ajoute une feuille (Sommaire) et la positionne en première position
    Set Ws = Wb.Worksheets.Add(before:=Wb.Sheets(1))
    Ws.Name = "SommaireFeuilles"
    
    'boucle sur les feuilles de calcul (hors feuille sommaire)
    For I = 2 To Wb.Worksheets.Count
            Cible = "'" & Wb.Worksheets(I).Name & "'!A1"
            'Crée le lien dans la feuille sommaire
            Ws.Hyperlinks.Add Anchor:=Ws.Cells(I, 1), Address:="", _
                SubAddress:=Cible, TextToDisplay:=Wb.Worksheets(I).Name
    Next I
End Sub

MsgBox Worksheets("Nom Feuille").Index

Sub envoiPlageCellules_Excel2002() 
'http://support.microsoft.com/default.aspx?scid=kb;en-us;816644 
Worksheets("Feuil1").Range("A1:B5").Select ' la plage de cellules à envoyer 

ActiveWorkbook.EnvelopeVisible = True 

With Worksheets("Feuil1").MailEnvelope 
    .Introduction = "bonjour , ci joint les données ..." 
    .Item.To = "destinataire@mail.fr" 
    .Item.Subject = "le sujet" 
    .Item.attachments.Add "C:\dossier\ma piece jointe.txt" 
    .Item.Send 
End With 
End Sub 

'Modifie le nom de la 2eme feuille de calcul
Worksheets(2).Name = "Nouveau Nom"
'Récupère le nom de la 2eme feuille de calcul
MsgBox Worksheets(2).Name

Dim Ot As Outline
'Définit le plan dans la feuille
Set Ot = Worksheets("Feuil1").Outline
'Affiche le plan jusqu'au 3eme niveau de ligne
Ot.ShowLevels rowLevels:=3

'Ajoute une info dans le pied de page gauche
Worksheets("Feuil1").PageSetup.LeftFooter = "La description perso"

'Ajoute le nom de l'utilisateur et la date dans le pied de page central
Worksheets("Feuil1").PageSetup.CenterFooter = Environ("username") & ", Le " & Date

'--- Ajoute une image dans l'entête gauche (à partir d'Excel202) ---
With Worksheets("Feuil1").PageSetup.LeftHeaderPicture
    .Filename = "http://www.developpez.net/forums/images/logo16.gif"
    .Height = 80 ' redéfinit la largeur de l'image
    .Width = 120 ' redéfinit la hauteur de l'image
End With

'Remarque: Il est nécessaire d'ajouter la chaîne "&G"
'de la propriété LeftHeader, afin que l'image s'affiche dans l'en-tête gauche?
'(info issue de l'aide en ligne Excel).
Worksheets("Feuil1").PageSetup.LeftHeader = "&G"
'------------------------------------------------------------------

'Ajoute une info dans l'entête droit en personnalisant
'la police, écriture en gras , taille 16 et texte souligné
Worksheets("Feuil1").PageSetup.RightHeader = "&""Arial,Gras""&16&U" & "Developpez.com"

With Worksheets("Feuil1")
    .PageSetup.CenterHorizontally = True
    .PageSetup.CenterVertically = True
    .PrintOut
End With

Dim Plage As Range
Dim Nm As Name
  
On Error Resume Next
'Boucle sur les noms du classeur
For Each Nm In Worksheets("Feuil1").Parent.Names
    Set Plage = Nm.RefersToRange
    
    If Not Plage Is Nothing Then
        'Vérifie si le nom appartient à la feuille
        If Worksheets("Feuil1").Name = Plage.Worksheet.Name Then _
            MsgBox Plage.Address
    End If

    Set Plage = Nothing
Next Nm

'Renvoie Vrai ou Faux
MsgBox Worksheets("Feuil1").ProtectContents

'Renvoie Vrai ou Faux
MsgBox Worksheets("Feuil1").ProtectDrawingObjects

'Protège la feuille en autorisant l'utilisation des tris
'(les cellules de la plage à trier doivent être déverrouillées)
Worksheets("Feuil1").Protect AllowSorting:=True

'Contrôle si le tri est autorisé après la mise en place de la protection
MsgBox Worksheets("Feuil1").Protection.AllowSorting
'Contrôle si l'utilisation des tableaux croisés dynamiques est autorisée
MsgBox Worksheets("Feuil1").Protection.AllowUsingPivotTables

'Contrôle le statut de protection
MsgBox Worksheets("Feuil1").ProtectionMode
'Protège la feuille
Worksheets("Feuil1").Protect UserInterfaceOnly:=True
'Contrôle le statut de protection après la modification
MsgBox Worksheets("Feuil1").ProtectionMode

'Renvoie Vrai ou Faux
MsgBox Worksheets("Feuil1").ProtectScenarios

    With Worksheets("Feuil1").QueryTables.Add(Connection:= _
            "ODBC;DSN=MS Access Database;DBQ=C:\dataBase.mdb;DefaultDir=C:;DriverId=25;" & _
            "FIL=MS Access;MaxBufferSize=2048;PageTimeout=5;", Destination:=Range("E3"))
        
        .CommandText = "SELECT Table1.CodeClient, Table1.CityName, Table1.NomClient " & _
            "FROM `C:\dataBase`.Table1 Table1 WHERE Table1.CityName='condrieu'"
        
        .Name = "Ma requête dans Access"
        .FieldNames = True
        .RowNumbers = False
        .FillAdjacentFormulas = False
        .PreserveFormatting = True
        .RefreshOnFileOpen = False
        .BackgroundQuery = True
        .RefreshStyle = xlInsertDeleteCells
        .SavePassword = True
        .SaveData = True
        .AdjustColumnWidth = True
        .RefreshPeriod = 0
        .PreserveColumnInfo = True
        .Refresh BackgroundQuery:=False
    End With

'Récupère le contenu de la cellule A1
MsgBox Worksheets("Feuil1").Range("A1")

'Dans cet exemple les deux lignes de macro spécifient la même plage de cellules:

  'Paramètre chaque cellule de la plage pour centrer le texte
  Worksheets("Feuil1").Range("A1:B10").HorizontalAlignment = xlCenter

  'Insère du texte dans chaque cellule de la plage
  Worksheets("Feuil1").Range(Cells(1, 1), Cells(10, 2)).Value = "x"

Dim i As Long

'Renvoie le numéro de ligne de la dernière cellule non vide dans la colonne A.
i = Worksheets("Feuil1").Range("A65536").End(xlUp).Row

MsgBox Worksheets("Feuil1").Range("A" & i)
MsgBox Worksheets("Feuil1").Cells(i, 1)

'Applique la couleur jaune dans la 2eme ligne
Worksheets("Feuil1").Rows(2).Interior.ColorIndex = 6

'Applique la couleur jaune dans les lignes 5 à 8
Worksheets("Feuil1").Rows("5:8").Interior.ColorIndex = 6

Dim i As Integer, j As Integer
Dim Cell As Range

Application.ScreenUpdating = False
    
    'Récupère le numero de ligne de la dernière cellule
    'non vide dans la colonne A.
    i = Worksheets("Feuil1").Range("A65536").End(xlUp).Row
    
    'boucle de la dernière à la premiere ligne
    For j = i To 1 Step -1
        'Vérifie si les cellules de la colonne A sont vides
        'et les supprime si c'est le cas.
        If Worksheets("Feuil1").Cells(j, 1) = "" Then _
            Worksheets("Feuil1").Rows(j).Delete
        
    Next j
    
Application.ScreenUpdating = True

'Limite le déplacement à la plage A1:E50, dans la 2eme feuille.
Worksheets(2).ScrollArea = "A1:E50"
MsgBox "Le déplacement est limité à la plage " & Worksheets(2).ScrollArea

Worksheets(2).ScrollArea = ""

'Ajoute une forme automatique (Rectangle) dans la feuille 
With Worksheets("Feuil1").Shapes.AddShape(msoShapeRectangle, 40, 80, 140, 50) 
    .Name = "NomForme" 
    .TextFrame.Characters.Text = "Le texte dans la forme" 
End With 

Dim Obj As Shape

'Compte le nombre de formes dans la feuille
MsgBox "Nombre de formes dans la feuille: " & Worksheets("Feuil1").Shapes.Count

'Boucle sur les formes contenues dans la feuille
For Each Obj In Worksheets("Feuil1").Shapes
    Select Case Obj.Type
        '--- MsoShapeType peut être une des constantes suivantes ---
        '-----------------------------------------------------------
        
            'Consultez aussi les constantes AutoShapeType pour identifier les différents
            'types de formes automatiques msoAutoShape.
        Case msoAutoShape: MsgBox "Forme automatique: " & Obj.Name
        'Case msoCallout
        Case msoChart: MsgBox "Graphique: " & Obj.Name
        Case msoComment: MsgBox "Commentaire: " & Obj.Name
        Case msoDiagram: MsgBox "Diagramme/Organigramme: " & Obj.Name
        Case msoEmbeddedOLEObject: MsgBox "Objet incorporé: " & Obj.Name
            'Nota:
            'Chaque bouton des filtres automatiques est considéré
            'comme un objet formulaire (zone de liste/DropDown).
        Case msoFormControl: MsgBox "Objet formulaire: " & Obj.Name
        Case msoFreeform: MsgBox "Forme libre: " & Obj.Name
        Case msoGroup: MsgBox "Groupe: " & Obj.Name
        Case msoLine: MsgBox "Ligne: " & Obj.Name
        Case msoLinkedOLEObject: MsgBox "Objet incorporé lié au fichier: " & Obj.Name
        Case msoOLEControlObject: MsgBox "Objet de la boîte à outils Contrôle: " & Obj.Name
        Case msoPicture: MsgBox "Image: " & Obj.Name
            'msoShapeTypeMixed permet de vérifier si une plage de formes contient
            'des types d'objets différents:
            'Par exemple: If Selection.ShapeRange.Type = msoShapeTypeMixed Then
        'Case msoShapeTypeMixed: MsgBox "Combinaison de formes"
        Case msoTextBox: MsgBox "Zone de texte: " & Obj.Name
        Case msoTextEffect: MsgBox "WordArt: " & Obj.Name
    End Select
Next Obj